Как заставить Windows проверить наличие обновлений?

Помимо обычного способа использования Windows Update, вы можете принудительно выполнить проверку из командной строки.

Откройте интерпретатор команд администратора и запустите его:

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe является клиентом автообновления Windows Update и используется для проверки наличия доступных обновлений (для различных версий платформы MS Windows) из Microsoft Update.

Это не приводит к принудительной установке.

Вы можете проверить и установить обновления автоматически с помощью скрипта. Это будет работать как в XP, так и в Windows 7.

Есть несколько скриптов, доступных для загрузки, вот мой :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete. Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop

Вы запускаете его из командной строки вот так:

cscript wsusupdate.vbs

Мой сценарий лишь минимально работоспособен, но все же может быть полезен. Есть и другие подобные скрипты с множеством дополнительных возможностей, попробуйте поискать в Google.

Чтобы проверить наличие обновлений, перейдите в Панель управления, Безопасность, Обновление Windows, затем нажмите кнопку “Проверить наличие обновлений”.

Другой способ принудить к истинному пересканированию для обновлений - стереть шифер с чистого листа, удалив все обновления, хранящиеся в %windir%\Windows\SoftwareDistribution\Download :

NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

Затем перейдите к Windows Update и “Проверьте наличие обновлений”. Это может занять час, поскольку проверяется каждый обновляемый файл на системном томе (последующие “Проверки обновлений” будут быстрыми). Такой подход устраняет ошибки, неудачные обновления и дает чистую, современную систему, по крайней мере, в той степени, в которой ее видит MS.

Я использую инструмент второй стороны под названием wuinstall для обновления установки свежих окон. с его помощью вы можете автоматизировать весь процесс обновления, включая автоматическую перезагрузку. я думаю, что это один из самых быстрых способов обновить свежие окна без участия пользователя.

Я обнаружил, что если в качестве части своей новой установки на Windows 7 вы обновили IE или еще не запустили IE и ответили на вступительные вопросы, то обновление Windows Update выдаст вам ошибку. Я также не нашел способа переключить Windows Update на Microsoft Update без прохождения через графический интерфейс, поэтому я вручную запустил IE, инициализировал его, а затем настроил Windows Update через графический интерфейс, чтобы можно было переключиться на Microsoft Update и избежать первоначальной ошибки. Ваш пробег может отличаться.

Я успешно выполнил шаги, описанные в этом сообщении post , установив IE8 & WI4.5 , оно вызовет автоматическое обновление для начала загрузки.